X: 1
T:Lovely Nancy,with (4)variations. JJo.011
B:J.Jones MS,1801,N.Shrops.
N:Tune found in MSs of Joshua Jackson (Yorkshire), John Clare (Northants)
N:and Winder (Wyresdale, Lancs).
A:N Shropshire
D:J.Jackson version may be heard on "The Miller's Jig"
D:by Magnetic North YDWCD005
Z:Neil Brookes 2006
M:3/4
L:1/8
Q:1/4=120
K:D
{g}f>e|d2d2d>f|e2e2e>g|f2d'agf|{f}e4{g}Tf>e|
d2d2d>f|e2e2d'>b|a>b a>f Te>f|d4:|
|:f>g|a2a2d'>b|{b}a4Tf>g|a2a2d'f|{f}e4{g}Tf>e|
d2d2d>f|e2e2d'>b|a>b a>f Te>f|d4:|
|:"var 1st"f>e|dAfd {b}ag/f/|eAge {c'}ba/g/|fdaf d'>f|Te2eb a/g/f/e/|
dAfd {b}ag/f/|eAge {c'}ba/g/|fd' {b}ag/f/ a/g/f/e/|{e}d4:|
|:f>g|afdd'c'b|b2a2f>g|a/d/e/f/ g/a/b/c'/ d'>f|Tf2eb a/g/f/e/|
dAfd {b}ag/f/|eAge {c'}ba/g/|fd' {b}ag/f/ a/g/f/e/|{e}d4:|
|:"var 2nd"{g}f>e|d2(3def (3afd|e2(3efg (3fad'|\
(3DFA (3fda (3d'af|{f}e4 {g}f>e|
d2(3def (3afd|e2(3efg (3fad'|(3bge (3afd (3gec|d4:|
|:f>g|a2 (3abc' (3d'c'b|a2 (3afg (3afg|(3abc' (3d'c'b (3afd|{d}e4 {g}f>e|
d2(3def (3afd|e2(3efg (3fd'c'|(3d'c'b (3afd (3gfe|d4:|
|:"var 3rd"f>e|(3dAF (3dAF (3def|(3ecA (3ecA (3efg|\
(3fdA (3fdA (3fad'|{f}e4f>e|
(3dAF (3dAF (3def|(3ecA (3ecA (3efg|(3fad' (3afd (3gec|d4:|
|:{g}f>g|(3afd (3dfa (3d'c'b|a4f>g|(3afd (3dfa (3d'c'b|{f}e4{g}f>e|
(3dFA (3dFA (3def|(3eAc (3eAc (3efg|(3fda (3d'af (3gec|d4:|
|:"var 4th"{g}f>e|d/A/B/c/ d/e/f/g/ a/f/e/d/|\
e/A/c/d/ e/f/g/a/ b/g/f/e/|f/d/e/f/ g/a/b/c'/ d'>f|Tf2e>gf>e|
d/A/B/c/ d/e/f/g/ a/f/e/d/|e/A/c/d/ e/f/g/a/ b/g/f/e/|\
fd' a/f/d/B/ g/e/c/A/|d2D2:|
|:f>g|a/d/e/f/ g/a/b/c'/ {e'}d'c'/b/|b2a2f>g|\
a/f/g/a/ b/c'/d'/c'/ b/a/g/f/|Tf2 e>gTf>e|
d/A/B/c/ d/e/f/g/ a/f/e/d/|e/A/c/d/ e/f/g/a/ b/g/f/e/|\
fd' a/a/f/d/ g/g/e/c/|d2D2:|


[P=get.cgi V=1/1 B=0 scale=0.60 512x512 ]
filesizedescription
Tune-80159-JonesJ.abc 1643 ABC music file with the extracted tune(s)
Tune-80159-JonesJ.txt 1643 Plain-text file with the extracted tune(s)
Tune-80159-get.log 3234 Log file, useful mostly for debugging
These files should be available for 24 hours.